Tìm hàm tính tháng trong excel

[Nambienhoa]

Em có 1 file tính tháng trong năm mà chưa biết áp dụng công thức nào. Nhờ ace giúp giùm. Em có đính kèm file bên dưới

 

[BuiQuangThuan]

Em có 1 file tính tháng trong năm mà chưa biết áp dụng công thức nào. Nhờ ace giúp giùm. Em có đính kèm file bên dưới

Tìm hiểu thêm hàm datedif coi

 

[Nambienhoa]

Tìm hiểu thêm hàm datedif coi

Hàm datedif là hàm tính chênh lệch giữa tháng, ngày, năm thôi ah

Bài đã được tự động gộp: 26/10/22

Hàm datedif là hàm tính chênh lệch giữa tháng, ngày, năm thôi ah

Bên em họ bắt tìm hàm để tính năm 1997 là bao nhiêu tháng, năm 1998 là bao nhiêu tháng và năm 199 là bao nhiêu tháng?

Từ Tháng	Đến Tháng
01/1997	11/1999

 

[levant0908]

bạn thử hàm này xem
=DATEDIF(B2,C2,"m")
Office của mình k có hàm này nên chưa test được

 

[Phuocam]

Hàm datedif là hàm tính chênh lệch giữa tháng, ngày, năm thôi ah

Bên em họ bắt tìm hàm để tính năm 1997 là bao nhiêu tháng, năm 1998 là bao nhiêu tháng và năm 199 là bao nhiêu tháng?

Từ Tháng	Đến Tháng
01/1997	11/1999

.

Sao giống tính số tháng đóng bảo hiểm xã hội ?

@levant0908 : Họ yêu cầu tính từng năm, không phải tính tổng.

Nhập ngày đầu năm của năm cần tính trong B6, mẫu: 1/1/1997.

Công thức mảng trong C6:

=SUM(IFERROR(DATEDIF(IF($B$2:$B$3<B6,B6,$B$2:$B$3),IF($C$2:$C$3>EDATE(B6,12),EDATE(B6,12),$C$2:$C$3),"m"),0))

Nhớ kết thúc bằng Ctrl+Shift+Enter.

.

 

[Nambienhoa]

@levant0908 : Họ yêu cầu tính từng năm, không phải tính tổng.

Anh Van làm trong file em gửi giùm em ha. Em tính hoài không ra

 

[hoangtuaotrang_hp_vn]

Anh Van làm trong file em gửi giùm em ha. Em tính hoài không ra

Làm theo hướng dẫn của anh Phuocam nhé

 

[Nambienhoa]

Làm theo hướng dẫn của anh Phuocam nhé

Năm 1997, năm 1998 thì công thức ra đúng rồi nhưng năm 1999 thì công thức bị sai (nếu tính nhẩm tính từ tháng 01/1999 đến tháng 11/1999 là 11 tháng) mà công thức ra có 10 tháng, tháng 01/2021 đến tháng 04/2021 là 4 tháng, công thức ra có 3 tháng. Anh Phước xem lại giùm em với nhé.

 

[Phan Thế Hiệp]

Năm 1997, năm 1998 thì công thức ra đúng rồi nhưng năm 1999 thì công thức bị sai (nếu tính nhẩm tính từ tháng 01/1999 đến tháng 11/1999 là 11 tháng) mà công thức ra có 10 tháng, tháng 01/2021 đến tháng 04/2021 là 4 tháng, công thức ra có 3 tháng. Anh Phước xem lại giùm em với nhé.

Với A6: Ax chỉ điền các năm muốn tìm. Thử:

B6=COUNT(1/(--TEXT(EDATE(TRANSPOSE($B$2:$B$3),ROW($1:$600)-1),"[<="&TRANSPOSE($C$2:$C$3)&"]yyyy;")=A6))

Kết thúc bằng Ctrl+Shift+Enter, Fill xuống.

Thân

 

[Phuocam]

B6=COUNT(1/(--TEXT(EDATE(TRANSPOSE($B$2:$B$3),ROW($1:$600)-1),"[<="&TRANSPOSE($C$2:$C$3)&"]yyyy;")=A6))

.

Có thể dùng COUNTIFS để giải quyết nó , chỉ Enter và giảm 600 tháng trong công thức xuống còn 12 tháng.

Hahaha ...

.

 

[Nambienhoa]

Công thức đã hoàn thiện rồi. Cám ơn các anh nhiều nhé.

 

[Phuocam]

Năm 1997, năm 1998 thì công thức ra đúng rồi nhưng năm 1999 thì công thức bị sai (nếu tính nhẩm tính từ tháng 01/1999 đến tháng 11/1999 là 11 tháng) mà công thức ra có 10 tháng, tháng 01/2021 đến tháng 04/2021 là 4 tháng, công thức ra có 3 tháng. Anh Phước xem lại giùm em với nhé.

.

Hàm DATEDIF chỉ tính tháng đủ, muốn kết quả như bạn mong muốn, có thể cộng thêm 31 ngày trong công thức:

=SUM(IFERROR(DATEDIF(IF($B$2:$B$3<B6,B6,$B$2:$B$3),IF($C$2:$C$3>EDATE(B6,12),EDATE(B6,12),$C$2:$C$3+31),"m"),0))

.

 

[LmoovoenX]

=(YEAR($C$1)-YEAR(F6))*12+(MONTH($C$1)-MONTH(F6))+IF(DAY($C$1)>=DAY(F6),0,-1)
công thức này được không, C1 là ngày cuối, f6 là ngày đầu, mình đang dùng để tính số tháng của trẻ trong bảng khám sức khoẻ

sr, ko đọc kỹ cái vụ tính tháng trong mỗi năm

 

[Phan Thế Hiệp]

.

Có thể dùng COUNTIFS để giải quyết nó , chỉ Enter và giảm 600 tháng trong công thức xuống còn 12 tháng.

Hahaha ...

.

Bạn hiền cười mình dùng mảng 600 tháng hén. Bây giờ mình dùng "quái chiêu" đấu hữu chiêu Counifs() 12 tháng Enter của bạn hiền nè:

B6=SUMPRODUCT(TEXT(TEXT($B$2:$C$3,"yyyymm")+{0,1}-(A6&"01"),"[<0]\0;[<12]0;\12")*{-1,1})

Enter nè, fill xuống nè.

Khà khà khà

 

[ptm0412]

Công thức đơn giản, nhờ suy luận đơn giản. Chỉ là If nên chỉ enter. (Nhìn mấy công thức khủng là thấy sợ)

B6=IF(AND(YEAR($B$2)<A6,YEAR($C$2)>A6),12,IF(OR(A6=YEAR($B$2)),13-MONTH($B$2),IF(A6=YEAR($C$2),MONTH($C$2),0)))
Fill xuống

 

[Phan Thế Hiệp]

Công thức đơn giản, nhờ suy luận đơn giản. Chỉ là If nên chỉ enter. (Nhìn mấy công thức khủng là thấy sợ)

B6=IF(AND(YEAR($B$2)<A6,YEAR($C$2)>A6),12,IF(OR(A6=YEAR($B$2)),13-MONTH($B$2),IF(A6=YEAR($C$2),MONTH($C$2),0)))
Fill xuống

View attachment 282660

Nhưng câu hỏi ở bài #1 hổng có đơn giản , vì còn dòng B3: C3 cũng của Nguyễn Văn Thắng luôn anh ạ! Giả sử, thêm vài dòng nữa cho các thời đoạn khác thì công thức đơn giản không giải quyết được.

Thân

 

[ptm0412]

công thức đơn giản không giải quyết được.

Nếu 2 dòng thì tính ra 2 cột rồi cộng lại trong cột tổng. 4, 5 dòng thì làm 4, 5 cột. Sao không giải quyết được?
Nếu không muốn tách ra cộng vào thì cộng công thức. Dài nhưng dễ.

=IF(AND(YEAR($B$2)<A6,YEAR($C$2)>A6),12,IF(OR(A6=YEAR($B$2)),13-MONTH($B$2),
IF(A6=YEAR($C$2),MONTH($C$2),0)))+
IF(AND(YEAR($B$3)<A6,YEAR($C$3)>A6),12,IF(OR(A6=YEAR($B$3)),13-MONTH($B$3),
IF(A6=YEAR($C$3),MONTH($C$3),0)))

Nếu Excel 365 thì có thể làm gọn cột năm ngắn lại, công thức tháng cũng dài như vậy nhưng ít dòng hơn.

G6 =VSTACK(SEQUENCE(YEAR(C2)-YEAR(B2)+1,1,YEAR(B2)),SEQUENCE(YEAR(C3)-YEAR(B3)+1,1,YEAR(B3)))

Không có 365 thì cột A xóa dòng thừa cũng chẳng sao.



Ý chính của tôi là công thức khủng dù hay, dù cao siêu, nhưng giúp cho người mới làm excel chút chút thì họ khó điều chỉnh, khi có gì thay đổi lại phải chạy lên đây hỏi.

 

[Phan Thế Hiệp]

Nếu 2 dòng thì tính ra 2 cột rồi cộng lại trong cột tổng. 4, 5 dòng thì làm 4, 5 cột. Sao không giải quyết được?
Nếu không muốn tách ra cộng vào thì cộng công thức. Dài nhưng dễ.

=IF(AND(YEAR($B$2)<A6,YEAR($C$2)>A6),12,IF(OR(A6=YEAR($B$2)),13-MONTH($B$2),
IF(A6=YEAR($C$2),MONTH($C$2),0)))+
IF(AND(YEAR($B$3)<A6,YEAR($C$3)>A6),12,IF(OR(A6=YEAR($B$3)),13-MONTH($B$3),
IF(A6=YEAR($C$3),MONTH($C$3),0)))

View attachment 282663


Nếu Excel 365 thì có thể làm gọn cột năm ngắn lại, công thức tháng cũng dài như vậy nhưng ít dòng hơn.

G6 =VSTACK(SEQUENCE(YEAR(C2)-YEAR(B2)+1,1,YEAR(B2)),SEQUENCE(YEAR(C3)-YEAR(B3)+1,1,YEAR(B3)))

Không có 365 thì cột A xóa dòng thừa cũng chẳng sao.

View attachment 282664

Ý chính của tôi là công thức khủng dù hay, dù cao siêu, nhưng giúp cho người mới làm excel chút chút thì họ khó điều chỉnh, khi có gì thay đổi lại phải chạy lên đây hỏi.

Âu cũng là 1 giải pháp excel! 99 người đến 100 ý, anh ạ!

Thân